<bdo id="o26oq"><center id="o26oq"></center></bdo>
  • <xmp id="o26oq"><noscript id="o26oq"></noscript>
  • <table id="o26oq"><center id="o26oq"></center></table><table id="o26oq"><center id="o26oq"></center></table>
    專注電子技術學習與研究
    當前位置:單片機教程網 >> MCU設計實例 >> 瀏覽文章

    單片機時鐘設計

    作者:佚名   來源:本站原創   點擊數:  更新時間:2007年06月14日   【字體:
           X1226具有時鐘和日歷的功能,時鐘依賴時、分、秒寄存器來跟蹤,日歷依賴日期、星期、月和年寄存器來跟蹤,日歷可正確顯示至2099年,并具有自動閏年修正功能。擁有強大的雙報警功能,能夠被設置到任何時鐘/日歷值上,精確度可到1秒?捎密浖O置1Hz、4096Hz或32768Hz中任意一個頻率輸出。

           X1226提供一個備份電源輸入腳VBACK,允許器件用電池或大容量電容進行備份供電。采用電容供電時,用一個硅或肖特基二極管連接到Vcc和充電電容的兩端,充電電容連接到Vback管腳,注意不能使用二極管對電池充電(特別是鋰離子電池)。切換到電池供電的條件是Vcc=Vback-0.1V,正常操作期間,供電電壓Vcc必須高于電池電壓,否則電池電量將逐步耗盡。振蕩器采用外接32.768kH的晶體,產生的振蕩誤差可通過軟件對數字微調寄存器、模擬微調寄存器的數值進行調節加以修正,避免了外接電阻和電容的離散性對精度的影響。4Kb的EEPROM可用于存儲戶數據。

           電路組成及工作原理 

           X1226可與各種類型的的微控制器或微處理器接口,接口方式為串行的I2C接口。其中數據總線SDA是一個雙向引腳,用于輸入或輸出數據。其漏極開路輸出在使用過程中需要添加4.7~10kΩ的上拉電阻。本文介紹89C51單片機與X1226的接口方法,由于89C51單片機沒有標準的I2C接口,只能用軟件進行模擬。

                                                                           圖1


           為了更直觀地看到時間的變化,采用8位LED數碼管顯示年、月、日或時、分、秒,用PS7219A驅動LED數碼管,數碼管選擇0.5英寸共陰極紅色或綠色LED數碼管。由于PS7219A器件內含IMP810單片機監控器件,復位輸出高電平有效,因此在使用51系統時,無須添加監控器件,使用PS7219A的復位輸出給51單片機復位即可,監控電壓為4.63V。硬件設計原理圖如圖1所示。

           在硬件通電調試過程中,不能用手去觸摸X1226的晶體振蕩器,否則可能會導致振蕩器停振,恢復振蕩器起振的方法是關閉電源(包括備份電源)后重新上電。另外需要說明的是,測量振蕩器時,不要用示波器的探頭去測量X2的振蕩輸出,應該用探頭測量PHZ/IRQ的振蕩輸出,以確定是否起振和振蕩頻率是否準確,測量時建議在該腳加一個5.1kΩ的上拉電阻。

           軟件設計

           X1226內含實時時鐘寄存器(RTC)、狀態寄存器(SR)、控制寄存器(CONTROL)、報警寄存器(Alarm0、Alarm1)和客戶存儲數據的存儲器。由于實時時鐘寄存器和狀態寄存器需要進行頻繁的寫操作,因此其存儲結構為易失性SRAM結構。其他寄存器均為EEPROM結構,寫操作次數通常在10萬次以上。X1226初始化程序框圖如圖2所示,子程序YS4的作用是延時4μs。

                                                            圖2  

     

           ● 寫操作

           X1226初始化之后,單片機對X1226進行開始條件的設置,在寫CCR或EEPROM之前,主機必須先向狀態寄存器寫02H,確認應答信號,確認后寫入06H,再確認應答信號。確認后啟動了寫操作,首先發送高位地

    址,然后發送低位地址。X1226每收到一個地址字節后,均會產生一個應答信號。在兩個地址字節都收到之后,X1226等待8位數據。在收到8位數據之后,X1226再產生一個應答,然后單片機產生一個停止條件來終止傳送。

           X1226具有連續寫入的功能,每收到1字節后,響應一個應答,其內部將地址加一。當計數器達到該頁的末尾時,就自動返回到該頁的首地址。這意味著單片機可從某一頁的任何位置開始向存儲器陣列連續寫入64字節,或向CCR連續寫入8字節的數據。寫入X1226數據子程序:
        

           ● 讀操作

           在上電時,16位地址的默認值為0000H。X1226初始化操作之后,單片機對X1226進行開始條件的設置,在寫CCR或EEPROM之前,主機必須先向狀態寄存器寫02H,確認應答信號,確認后寫入06H,再確認應答信號。確認后啟動了寫操作,首先發送高位地址,然后發送低位地址。X1226每收到一個地址字節后,均會產生一個應答信號。單片機發送另一個開始條件,將R/W位設置為1,接著接受8位數據。單片機終止讀操作時,無需等待X1226的應答信號,單片機即可設置停止條件。讀出X1226數據子程序:
      

           ● 振蕩器頻率在線補償調節

           X1226集成了振蕩器補償電路,用戶可通過軟件在線對振蕩器頻率進行微調,這種微調通常針對兩種情況。一種情況是在25℃常溫下,對振蕩器因器件初始精度帶來的頻率偏差進行補償;第二種情況是對因溫度引起的頻率漂移進行補償。X1226內部設有數字微調寄存器(DTR)和模擬微調寄存器(ATR),兩個寄存器均為非易失性寄存器。數字微調寄存器具有3位數字微調位,調節范圍為-30~+30×10-6。模擬微調寄存器具有6個模擬微調位,調節范圍為-37~+116×10-6。

           對于因外界環境溫度變化引起的溫漂補償,要依據晶體的溫度系數,在存儲器中建立補償參數表,不同廠家晶體的溫度系數是不一樣的,應根據產品數據手冊進行選擇。

           為了能夠對溫漂進行補償,要求系統中設置一個溫度傳感器,并盡量讓它靠近X1226,這樣可以真實地反映振蕩器的溫度,原理圖如圖3所示。單片機首先通過系統溫度傳感器獲取環境溫度,并在補償參數表中獲取對應的補償值,然后將補償數據填寫到相應的微調寄存器中,就能實現溫漂補償的目的。

                                                                   圖3

           由于X1226具有精密的振蕩器補償功能,因此非常適合于環境溫度變化較大的應用場合,同時也降低了對晶體性能參數的要求

    下面還為廣大讀者介紹一個程序:

    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;   AT89C2051時鐘程序         ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;

    ;
    ;  定時器T0、T1溢出周期為50MS,T0為秒計數用, T1為調整時閃爍用,
    ;   P3.7為調整按鈕,P1口 為字符輸出口,采用共陽顯示管。
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           中斷入口程序              ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;
                  ORG 0000H        ;程序執行開始地址
                  LJMP      START  ;跳到標號START執行
                  ORG 0003H        ;外中斷0中斷程序入口
                  RETI                    ;外中斷0中斷返回
                  ORG 000BH        ;定時器T0中斷程序入口
                  LJMP      INTT0   ;跳至INTTO執行
                  ORG 0013H        ;外中斷1中斷程序入口
                  RETI                   ;外中斷1中斷返回
                  ORG 001BH        ;定時器T1中斷程序入口
                  LJMP      INTT1   ;跳至INTT1執行
                  ORG 0023H        ;串行中斷程序入口地址
                  RETI                    ;串行中斷程序返回
    ;
     ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
     ;;           主 程 序                 ;;
     ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;
          START: MOV   R0,#70H       ;清70H-7AH共11個內存單元
                       MOV   R7,#0BH       ;
    CLEARDISP: MOV   @R0,#00H       ;
                       INC   R0             ;
                       DJNZ  R7,CLEARDISP   ;
                       MOV   20H,#00H      ;清20H(標志用)
                       MOV   7AH,#0AH       ;放入"熄滅符"數據
                       MOV   TMOD,#11H      ;設T0、T1為16位定時器
                       MOV   TL0,#0B0H    ;50MS定時初值(T0計時用)
                       MOV   TH0,#3CH    ;50MS定時初值
                       MOV   TL1,#0B0H    ;50MS定時初值(T1閃爍定時用)
                       MOV   TH1,#3CH     ;50MS定時初值
                       SETB  EA             ;總中斷開放
                       SETB  ET0            ;允許T0中斷
                       SETB  TR0            ;開啟T0定時器
                       MOV   R4,#14H        ;1秒定時用初值(50MS×20)
        START1: LCALL DISPLAY        ;調用顯示子程序
                       JNB   P3.7,SETMM1    ;P3.7口為0時轉時間調整程序
                       SJMP  START1         ;P3.7口為1時跳回START1
    SETMM1:    LJMP SETMM     ;轉到時間調整程序SETMM
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           1秒計時程序              ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;T0中斷服務程序
            INTT0: PUSH  ACC           ;累加器入棧保護
                       PUSH  PSW           ;狀態字入棧保護
                       CLR   ET0           ;關T0中斷允許
                       CLR   TR0           ;關閉定時器T0
                       MOV   A,#0B7H       ;中斷響應時間同步修正
                       ADD   A,TL0         ;低8位初值修正
                       MOV   TL0,A         ;重裝初值(低8位修正值)
                       MOV   A,#3CH        ;高8位初值修正
                       ADDC  A,TH0         ;
                       MOV   TH0,A         ;重裝初值(高8位修正值)
                       SETB  TR0           ;開啟定時器T0
                       DJNZ  R4, OUTT0         ;20次中斷未到中斷退出
        ADDSS:  MOV  R4,#14H           ;20次中斷到(1秒)重賦初值
                       MOV   R0,#71H           ;指向秒計時單元(71H-72H)
                       ACALL ADD1              ;調用加1程序(加1秒操作)
                       MOV   A,R3              ;秒數據放入A(R3為2位十進制數組合)
                       CLR  C                 ;清進位標志
                       CJNE  A,#60H,ADDMM      ;
       ADDMM:  JC    OUTT0             ;小于60秒時中斷退出
                       ACALL CLR0              ;大于或等于60秒時對秒計時單元清0
                       MOV  R0,#77H           ;指向分計時單元(76H-77H)
                       ACALL ADD1              ;分計時單元加1分鐘
                       MOV   A,R3              ;分數據放入A
                       CLR   C                 ;清進位標志
                       CJNE  A,#60H,ADDHH      ;
         ADDHH: JC  OUTT0             ;小于60分時中斷退出
                       ACALL CLR0              ;大于或等于60分時分計時單元清0
                       MOV  R0,#79H           ;指向小時計時單元(78H-79H)
                       ACALL ADD1              ;小時計時單元加1小時
                       MOV   A,R3              ;時數據放入A
                       CLR   C                 ;清進位標志
                       CJNE  A,#24H,HOUR       ;
           HOUR: JC    OUTT0             ;小于24小時中斷退出
                       ACALL CLR0              ;大于或等于24小時小時計時單元清0
         OUTT0: MOV   72H,76H           ;中斷退出時將分、時計時單元數據移
                       MOV   73H,77H           ;入對應顯示單元
                       MOV   74H,78H           ;
                       MOV   75H,79H           ;
                       POP   PSW               ;恢復狀態字(出棧)
                       POP   ACC               ;恢復累加器
                       SETB  ET0               ;開放T0中斷
                       RETI                    ;中斷返回
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           閃動調時 程 序            ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;T1中斷服務程序,用作時間調整時調整單元閃爍指示
    INTT1:      PUSH    ACC                ;中斷現場保護
                    PUSH    PSW                ;
                    MOV     TL1,   #0B0H       ;裝定時器T1定時初值
                    MOV     TH1,   #3CH     ;
                    DJNZ    R2,INTT1OUT     ;0.3秒未到退出中斷(50MS中斷6次)
                    MOV     R2,#06H         ;重裝0.3秒定時用初值
                    CPL     02H             ;0.3秒定時到對閃爍標志取反
                    JB      02H,FLASH1      ;02H位為1時顯示單元"熄滅"
                    MOV     72H,76H       ;02H位為0時正常顯示
                    MOV     73H,77H       ;
                    MOV     74H,78H       ;
                    MOV     75H,79H       ;
    INTT1OUT: 

                    POP     PSW          ;恢復現場
                    POP     ACC           ;
                    RETI                  ;中斷退出
    FLASH1:  JB      01H,FLASH2    ;01H位為1時,轉小時熄滅控制
                    MOV     72H,7AH       ;01H位為0時,"熄滅符"數據放入分
                    MOV     73H,7AH       ;顯示單元(72H-73H),將不顯示分數據
                    MOV     74H,78H       ;
                    MOV     75H,79H       ;
                    AJMP    INTT1OUT      ;轉中斷退出
    FLASH2:  MOV     72H,76H       ;01H位為1時,"熄滅符"數據放入小時
                    MOV     73H,77H       ;顯示單元(74H-75H),小時數據將不顯示
                    MOV     74H,7AH       ;
                    MOV     75H,7AH       ;
                    AJMP    INTT1OUT      ;轉中斷退出
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           加1子 程 序              ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;
            ADD1: MOV  A,@R0       ;取當前計時單元數據到A
                       DEC  R0          ;指向前一地址
                       SWAP  A           ;A中數據高四位與低四位交換
                       ORL   A,@R0       ;前一地址中數據放入A中低四位
                       ADD  A,#01H      ;A加1操作
                       DA   A           ;十進制調整
                       MOV   R3,A        ;移入R3寄存器
                       ANL   A,#0FH      ;高四位變0
                       MOV   @R0,A       ;放回前一地址單元
                       MOV  A,R3        ;取回R3中暫存數據
                       INC  R0          ;指向當前地址單元
                       SWAP  A           ;A中數據高四位與低四位交換
                       ANL   A,#0FH      ;高四位變0
                       MOV  @R0,A       ;數據放入當削地址單元中
                       RET                  ;子程序返回
       ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           清零程序                  ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;對計時單元復零用
            CLR0: CLR   A           ;清累加器
                       MOV   @R0,A       ;清當前地址單元
                       DEC   R0          ;指向前一地址
                       MOV   @R0,A       ;前一地址單元清0
                       RET                      ;子程序返回
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           時鐘調整程序              ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;當調時按鍵按下時進入此程序
        SETMM:  cLR   ET0            ;關定時器T0中斷
                       CLR   TR0            ;關閉定時器T0
                       LCALL   DL1S           ;調用1秒延時程序
                       JB    P3.7,CLOSEDIS  ;鍵按下時間小于1秒,關閉顯示(省電)
                       MOV   R2,#06H        ;進入調時狀態,賦閃爍定時初值
                       SETB  ET1            ;允許T1中斷
                       SETB  TR1            ;開啟定時器T1
           SET2:  JNB   P3.7,SET1      ;P3.7口為0(鍵未釋放),等待
                       SETB   00H            ;鍵釋放,分調整閃爍標志置1
           SET4:  JB    P3.7,SET3      ;等待鍵按下
                       LCALL    DL05S          ;有鍵按下,延時0.5秒
                       JNB     P3.7,SETHH     ;按下時間大于0.5秒轉調小時狀態
                       MOV   R0,#77H        ;按下時間小于0.5秒加1分鐘操作
                       LCALL  ADD1           ;調用加1子程序
                       MOV   A,R3           ;取調整單元數據
                       CLR   C              ;清進位標志
                       CJNE  A,#60H,HHH     ;調整單元數據與60比較
              HHH: JC   SET4           ;調整單元數據小于60轉SET4循環
                       LCALL  CLR0           ;調整單元數據大于或等于60時清0
                       CLR   C              ;清進位標志
                       AJMP   SET4           ;跳轉到SET4循環
     CLOSEDIS:SETB   ET0           ;省電(LED不顯示)狀態。開T0中斷
                       SETB   TR0           ;開啟T0定時器(開時鐘)
     CLOSE:     JB     P3.7,CLOSE    ;無按鍵按下,等待。
                       LCALL  DISPLAY       ;有鍵按下,調顯示子程序延時削抖
                       JB     P3.7,CLOSE     ;是干擾返回CLOSE等待
      WAITH:     JNB    P3.7,WAITH     ;等待鍵釋放
                       LJMP   START1         ;返回主程序(LED數據顯示亮)
        SETHH:  CLR    00H           ;分閃爍標志清除(進入調小時狀態)
      SETHH1:  JNB   P3.7,SET5      ;等待鍵釋放
                       SETB         01H            ;小時調整標志置1
           SET6:  JB    P3.7,SET7      ;等待按鍵按下
                       LCALL    DL05S          ;有鍵按下延時0.5秒
                       JNB     P3.7,SETOUT    ;按下時間大于0.5秒退出時間調整
                       MOV   R0,#79H       ;按下時間小于0.5秒加1小時操作
                       LCALL   ADD1            ;調加1子程序
                       MOV   A,R3            ;
                       CLR   C                ;
                       CJNE  A,#24H,HOUU      ;計時單元數據與24比較
          HOUU:  JC   SET6             ;小于24轉SET6循環
                       LCALL  CLR0             ;大于或等于24時清0操作
                       AJMP   SET6             ;跳轉到SET6循環
       SETOUT: JNB    P3.7,SETOUT1     ;調時退出程序。等待鍵釋放
                       LCALL  DISPLAY          ;延時削抖
                       JNB    P3.7,SETOUT      ;是抖動,返回SETOUT再等待
                       CLR    01H              ;清調小時標志
                       CLR    00H              ;清調分標志
                       CLR    02H              ;清閃爍標志
                       CLR    TR1              ;關閉定時器T1
                       CLR    ET1              ;關定時器T1中斷
                       SETB   TR0              ;開啟定時器T0
                       SETB   ET0              ;開定時器T0中斷(計時開始)
                       LJMP  START1           ;跳回主程序
           SET1:  LCALL    DISPLAY          ;鍵釋放等待時調用顯示程序(調分)
                       AJMP     SET2             ;防止鍵按下時無時鐘顯示
           SET3:  LCALL    DISPLAY          ;等待調分按鍵時時鐘顯示用
                       AJMP     SET4
           SET5:  LCALL    DISPLAY          ;鍵釋放等待時調用顯示程序(調小時)
                       AJMP     SETHH1           ;防止鍵按下時無時鐘顯示
           SET7:  LCALL    DISPLAY          ;等待調小時按鍵時時鐘顯示用
                       AJMP     SET6
     SETOUT1:  LCALL    DISPLAY          ;退出時鐘調整時鍵釋放等待
                        AJMP    SETOUT           ;防止鍵按下時無時鐘顯示
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           顯示程序                  ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ; 顯示數據在70H-75H單元內,用六位LED共陽數碼管顯示,P1口輸出段碼數據,P3口作
    ; 掃描控制,每個LED數碼管亮1MS時間再逐位循環。
       DISPLAY: MOV   R1,#70H       ;指向顯示數據首址
                       MOV   R5,#0FEH      ;掃描控制字初值
            PLAY: MOV   A,R5          ;掃描字放入A
                       MOV   P3,A          ;從P3口輸出
                       MOV   A,@R1         ;取顯示數據到A
                       MOV   DPTR,#TAB     ;取段碼表地址
                       MOVC  A,@A+DPTR     ;查顯示數據對應段碼
                       MOV   P1,A          ;段碼放入P1口
                       LCALL  DL1MS         ;顯示1MS
                       INC   R1            ;指向下一地址
                       MOV   A,R5            ;掃描控制字放入A
                       JNB   ACC.5,ENDOUT    ;ACC.5=0時一次顯示結束
                       RL   A               ;A中數據循環左移
                       MOV   R5,A            ;放回R5內
                       AJMP  PLAY            ;跳回PLAY循環
      ENDOUT: SETB  P3.5            ;一次顯示結束,P3口復位
                       MOV    P1,#0FFH       ;P1口復位
                       RET                      ;子程序返回
              TAB: DB 0C0H,0F9H,0A4H,0B0H,99H,92H,82H,0F8H,80H,90H,0FFH
    ;共陽段碼表          "0""1""2" "3""4""5""6""7" "8""9""不亮"
    ;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;;           延時程序                  ;;
    ;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;
    ;
    ;1MS延時程序,LED顯示程序用
           DL1MS: MOV  R6,#14H
              DL1:   MOV  R7,#19H
              DL2:   DJNZ  R7,DL2
                        DJNZ  R6,DL1
                        RET
    ;20MS延時程序,采用調用顯示子程序以改善LED的顯示閃爍現象
       DS20MS: ACALL   DISPLAY
                       ACALL  DISPLAY
                       ACALL  DISPLAY
                       RET
    ;延時程序,用作按鍵時間的長短判斷
          DL1S:   LCALL      DL05S
                       LCALL      DL05S
                       RET
        DL05S:   MOV        R3,#20H      ;8毫秒*32=0.196秒
       DL05S1:  LCALL      DISPLAY
                       DJNZ       R3,DL05S1
                       RET
    ;
                       END                     ;程序結束

    關閉窗口

    相關文章

    性交浓厚在线观看
    <bdo id="o26oq"><center id="o26oq"></center></bdo>
  • <xmp id="o26oq"><noscript id="o26oq"></noscript>
  • <table id="o26oq"><center id="o26oq"></center></table><table id="o26oq"><center id="o26oq"></center></table>